if (word(2 $loadinfo()) != [pf]) {
	load -pf $word(1 $loadinfo());
	return;
};

#	Copyright (c) 2004 BlackJac@EFNet
#
#	Version: 1.0.2004.06.06.1
#
#	This script is used with #idlerpg. It will prevent you from
#	speaking in the channel. It will also log you into the bot
#	automatically. See http://www.idlerpg.com/ for more information.

package idlerpg;

# Bot hostname for #idlerpg:
assign IDLERPG_HOSTNAME bot@idle.rpg;

# Login password for #idlerpg:
assign IDLERPG_PASSWORD mypassword;

# Login username for #idlerpg:
assign IDLERPG_USERNAME myusername;

^on ^input "*" {
	if (C != [#idlerpg] || [$*] =~ [/*]) {
		sendline $*;
	} else {
		xecho -b -c You cannot speak in #idlerpg;
	};
};

^on #-join 4 "% #idlerpg *" {
	if ([$0] == servernick()) {
		userhost idlerpg -direct -cmd {
			if ([$3@$4] == IDLERPG_HOSTNAME) {
				msg idlerpg login $IDLERPG_USERNAME $IDLERPG_PASSWORD;
			};
		};
	} else if ([$0] == [idlerpg] && [$2] == IDLERPG_HOSTNAME) {
		msg idlerpg login $IDLERPG_USERNAME $IDLERPG_PASSWORD;
	};
};