if (word(2 $loadinfo()) != [pf]) {
	load -pf $word(1 $loadinfo());
	return;
};

#	Copyright (c) 2004 BlackJac@EFNet
#
#	Version: 1.2.2005.03.04.1
#
#	This script will automatically replace misspelled words with correctly
#	spelled words before they are sent to their target. You must provide
#	your own list of words.

package spellcheck;

# List of properly spelled words to replace incorrectly spelled words (leave
# a space between words; each word must line up in order with the incorrectly
# spelled words):
assign SPELLCHECK_RIGHT and and can't don't I I'd I'll I'm I've is that the what won't;

# List of improperly spelled words to be replaced by correctly spelled words
# (leave a space between words; each word must line up in order with the
# correctly spelled words):
assign SPELLCHECK_WRONG adn nad cant dont i i'd i'll i'm i've si taht teh waht wont;

^on ^input '*\\\\[$$SPELLCHECK_WRONG\\\\]*' {
	if ([$*] =~ [/*] && findw($0 /m /me /msg /notice /say) == -1) {
		sendline $*;
	} else {
		fec ($*) ss {
			if (ss != [ ]) {
				@ :buffer #= ss;
			} else {
				@ :line #= [${findw($buffer $SPELLCHECK_WRONG) > -1 ? copattern($buffer SPELLCHECK_WRONG SPELLCHECK_RIGHT) : buffer} ];
				@ :buffer = [];
			};
		};
		if (@buffer) {
			@ :line #= findw($buffer $SPELLCHECK_WRONG) > -1 ? copattern($buffer SPELLCHECK_WRONG SPELLCHECK_RIGHT) : buffer;
		};
		sendline $line;
	};
};