if (word(2 $loadinfo()) != [pf]) {
	load -pf $word(1 $loadinfo());
	return;
};

#	Copyright (c) 2004 BlackJac@EFNet
#
#	Version: 1.2.2004.09.19.1
#
#	This script will check the current weather conditions according
#	to http://www.weatherroom.com/ and display the results on your
#	status bar. /weather will force an immediate update or let you
#	see the weather conditions for other locations. /forecast will
#	display the forecast.
#
#	In order to see the current weather conditions on your status
#	bar, you must put %{0}3 in your STATUS_FORMAT, STATUS_FORMAT1
#	or STATUS_FORMAT2 setting.

package weather;

# Default zip code (US only) or ICAO code to use (see the complete list
# of ICAO codes at http://www.airport-technology.com/icao-codes/):
assign WEATHER_CODE KNYC;

# Display current weather conditions on the status bar:
assign WEATHER_STATUSBAR 1;

# Wait this number of seconds since the last status bar update before
# performing another update:
assign WEATHER_UPDATE 900;

# Format of current weather conditions status bar indicator (only mod-
# ify this if you know what you are doing!):
set STATUS_USER3 \${weather && WEATHER_STATUSBAR ? [\[Weather\: $word(0 $after(-1 # $weather))°F, $after(# $before(-1 # $weather))\]] : []};

# This must be set to ON to properly display the current weather con-
# ditions on your status bar:
set STATUS_DOES_EXPANDOS on;

alias forecast (code default "$WEATHER_CODE", void) {
	if (isnumber($code)) {
		^on ^dcc_raw "% weatherroom.com E 80" #;
		if (:connect = connect(weatherroom.com 80)) {
			@ weather.forecast = code;
			^on ^dcc_raw "$connect weatherroom.com C" {
				@ weather.forecast = [];
				^on dcc_raw -"$0 weatherroom.com D *";
				^on dcc_raw -"$0 weatherroom.com C";
			};
			^on ^dcc_raw "$connect weatherroom.com D *" #;
			^on ^dcc_raw "$connect weatherroom.com D <Time> *" {
				^on ^dcc_raw "$0 weatherroom.com D *" {
					xecho -b -c ,----------------------------------------------.;
					xecho -b -c |     Extended Forecast for Zip Code $[5]weather.forecast     |;
					xecho -b -c |----------------------------------------------|;
					xecho -b -c |       Day       | High  |  Low  | Conditions |;
					xecho -b -c |-----------------+-------+-------+------------';
					@ :forecast.1 = strip(Â $after(1 < $before(2 & $*)));
					@ :forecast.2 = strip(Â $after(11 < $before(4 & $*)));
					@ :forecast.3 = strip(Â $after(21 < $before(6 & $*)));
					@ :forecast.4 = strip(Â $after(31 < $before(8 & $*)));
					@ :forecast.5 = strip(Â $after(41 < $before(10 & $*)));
					fe (1 2 3 4 5) ff {
						if (forecast[$ff]) {
							xecho -b -c | $[15]split(_ $before(> $forecast[$ff])) | $[5]afterw(<High> $beforew(</High> $forecast[$ff])) | $[5]afterw(<Low> $beforew(</Low $forecast[$ff])) | $afterw(<Conditions> $beforew(</Conditions> $forecast[$ff]));
						};
					};
					xecho -b -c `-----------------------------------------------;
				};
				^on ^dcc_raw "$0 weatherroom.com D </Forecast>" {
					^on ^dcc_raw "$0 weatherroom.com D *" #;
					^on dcc_raw -"$0 weatherroom.com D </Forecast>";
					^on dcc_raw -"$0 weatherroom.com D <Time> *";
				};
			};
			msg =$connect GET /xml/ext/$code HTTP/1.1$chr(13);
			msg =$connect User-Agent: Mozilla/4.0 \(compatible\; $J\; $uname(%s %r)\;\)$chr(13);
			msg =$connect Host: weatherroom.com$chr(13);
			msg =$connect Connection: close$chr(13 10);
		};
		^on dcc_raw -"% weatherroom.com E 80";
	};
};

alias weather (code default "$WEATHER_CODE", void) {
	if (code) {
		^on ^dcc_raw "% weatherroom.com E 80" #;
		if (:connect = connect(weatherroom.com 80)) {
			^on ^dcc_raw "$connect weatherroom.com C" {
				^on dcc_raw -"$0 weatherroom.com D *";
				^on dcc_raw -"$0 weatherroom.com C";
			};
			^on ^dcc_raw "$connect weatherroom.com D *" {
				switch ($3) {
					(<Conditions>) {
						@ weather.info #= [#$afterw(<Conditions> $beforew(</Conditions> $*))];
					}
					(<Location>) {
						@ weather.info = afterw(<Location> $beforew(</Location> $*));
					}
					(<Temp>) {
						@ weather.info #= [#$afterw(<Temp> $before(& $*))];
					};
				};
			};
			msg =$connect GET /xml/${isnumber($code) ? [zip] : [loc]}/$code HTTP/1.1$chr(13);
			msg =$connect User-Agent: Mozilla/4.0 \(compatible\; $J\; $uname(%s %r)\;\)$chr(13);
			msg =$connect Host: weatherroom.com$chr(13);
			msg =$connect Connection: close$chr(13 10);
			until (weather.info || cnt == 60) {
				pause 0.5;
				@ :cnt++;
			};
			if (functioncall()) {
				@ function_return = weather.info;
			} else {
				xecho -b -c Weather \($before(# $weather.info)\): $word(0 $after(-1 # $weather.info))°F, $after(# $before(-1 # $weather.info));
			};
			if (code == WEATHER_CODE) {
				@ weather = weather.info;
				if (WEATHER_STATUSBAR) {
					parsekey refresh_status;
				};
			};
			@ weather.info = [];
		};
		^on dcc_raw -"% weatherroom.com E 80";
	};
};

alias weather.statusbar (void) {
	if (WEATHER_STATUSBAR) {
		^timer -ref weather -rep -1 $WEATHER_UPDATE {
			@ weather($WEATHER_CODE);
		};
		@ weather($WEATHER_CODE);
	} else {
		@ weather = [];
		^timer -del weather;
		parsekey refresh_status;
	};
};

if (!timerctl(refnum weather)) {
	weather.statusbar;
};